Witamy na forum PC Format Zapraszamy do REJESTRACJI


Użytkownicy przeglądający ten wątek: 1 gości

VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie

#1
VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie
Witam,
Mam makro w wordzie:
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find
.Text = "section"
.Replacement.Text = "Sekcja"
.Forward = True
.Wrap = wdFindAsk
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

Wyszukuje słowo "section" i zamienia na "sekcja" w całym dokumencie. Jak to zrobić dla Powerpointa? Proszę o pomoc. Bardzo pilne.

Pozdrawiam.
 System operacyjny: windows_seven Przeglądarka: chrome
#2
RE: VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie
A nie prościej: Edycja > Znajdź > Zamień wszystko ?
Nie pomagam na PW (ew. odpłatnie). 
I osobom z roszczeniowym podejściem. I osobom niedbającym o poprawność językową.
Jak podawać logi
Jeśli nie odpowiadam w danym wątku przez >3 dni - proszę o przypomnienie na PW z linkiem do wątku w treści.




 System operacyjny: windows_xp_2003 Przeglądarka: firefox
#3
RE: VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie
To będzie parę słów. Wystarczy mi przykład do jednego, ale domyślnie ma być makro (jeden przycisk), który zmienia wiele- oszczędza dużo czasu.
Dla potomności. Ktoś z innego forum zabłysnąłWesoły
Sub zamiana_SensetiveCase()
'MVP OShon from VBATools.pl
Dim shp As Shape, sl&
For sl = 1 To ActivePresentation.Slides.Count
For Each shp In ActivePresentation.Slides(sl).Shapes
With shp.TextFrame.TextRange
.Text = Replace(.Text, _
Find:="ala ma kota", _
Replace:="zamieniono")
End With
Next
Next sl
End Sub

Sub zamiana_SensetiveUniSex()
'MVP OShon from VBATools.pl
Dim shp As Shape, sl&
For sl = 1 To ActivePresentation.Slides.Count
For Each shp In ActivePresentation.Slides(sl).Shapes
With shp.TextFrame.TextRange
.Text = Replace(LCase(.Text), _
Find:="ala ma kota", _
Replace:="zamieniono")
End With
Next
Next sl
End Sub
 System operacyjny: windows_seven Przeglądarka: chrome
#4
RE: VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie
Nowy moduł:
Kod:
Option Explicit

Sub ReplaceText()
    
    Dim oSld As Slide
    Dim oShp As Shape
    Dim oTxtRng As TextRange
    Dim oTmpRng As TextRange
    Dim strWhatReplace As String, strReplaceText As String
    
    strWhatReplace = "section"
    strReplaceText = "sekcja"
    
    For Each oSld In ActivePresentation.Slides
        For Each oShp In oSld.Shapes
            Set oTxtRng = oShp.TextFrame.TextRange
            Set oTmpRng = oTxtRng.Replace( _
            FindWhat:=strWhatReplace, _
            Replacewhat:=strReplaceText, _
            WholeWords:=True)
            
            Do While Not oTmpRng Is Nothing
                Set oTxtRng = oTxtRng.Characters _
                (oTmpRng.Start + oTmpRng.Length, oTxtRng.Length)
                Set oTmpRng = oTxtRng.Replace( _
                FindWhat:=strWhatReplace, _
                Replacewhat:=strReplaceText, _
                WholeWords:=True)
            Loop
        Next oShp
    Next oSld
End Sub

PS. Kod wyszuka "section" i "Section", ale zamieni oba przypadki na "sekcja".
Nie pomagam na PW (ew. odpłatnie). 
I osobom z roszczeniowym podejściem. I osobom niedbającym o poprawność językową.
Jak podawać logi
Jeśli nie odpowiadam w danym wątku przez >3 dni - proszę o przypomnienie na PW z linkiem do wątku w treści.




 System operacyjny: windows_xp_2003 Przeglądarka: firefox
Programy: Polecane / Nowe / Inne



Użytkownicy forum szukali:
powerpoint zamiana danych słówvba jak zamienić tekst w power pointvba zamień

Podobne wątki (VBA w Powerpoint- zamiana danego tekstu na inny w całym dokumencie)
Wątek: Autor Odpowiedzi: Wyświetleń: Ostatni post
  [VBA Excel] Wyszukiwanie wartości w kolumnie Pioro 2 16842 22.06.2020, 18:27
Ostatni post: Pioro
  VBA excel dmjs 6 17590 17.04.2019, 10:20
Ostatni post: ptrick
  Zamiana całego zestawu znaków wg przyporządkowania BarHorab 5 14990 19.12.2018, 16:45
Ostatni post: Szachista

Skocz do: